Increased camera distance (Warcraft 3 classic)

The only way I have found to increase the camera distance is to modify the maps themself.

---

Setup

1. Open the map of interest with the “World Editor”
2. Follow the menu “Module” -> “Trigger Editor”
3. Create a new trigger and name it “Camera Distance”
4. Follow the menu “Edit” -> “Convert to Custom Script”
5. Replace the shown default script with the one below
6. Save the map and close the “World Editor”

function Change_Camera_Distance takes nothing returns nothing

  local integer msgLen = 0
  local string msgArg = null
  local integer camDist = 0

  if GetLocalPlayer() == GetTriggerPlayer() then
    if SubString(GetEventPlayerChatString(), 0, 6) == "-dist " then
      set msgLen = StringLength(GetEventPlayerChatString())
      set msgArg = SubString(GetEventPlayerChatString(), 6, msgLen)
      set camDist = S2I(msgArg)
      if camDist <= 1650 then
        set camDist = 1650
      elseif camDist >= 4000 then
        set camDist = 4000
      endif
      call SetCameraField(CAMERA_FIELD_TARGET_DISTANCE, camDist, 0.00)
    endif
  endif

endfunction

//=============================================================================

function InitTrig_Camera_Distance takes nothing returns nothing

  local trigger distTrig = CreateTrigger()
  local integer playerIdx = 0

  loop
    exitwhen playerIdx == bj_MAX_PLAYERS
    call TriggerRegisterPlayerChatEvent(distTrig, Player(playerIdx), "", false)
    set playerIdx = playerIdx + 1
  endloop

  call TriggerAddAction(distTrig, function Change_Camera_Distance)

endfunction

The script has been written in Jass (Scripting language for Warcraft 3).

---

Usage

1. Open the modified map with Warcraft 3
2. Press enter top open up the chat
3. Write “-dist [1650..4000]” in the chat
4. Press enter again to apply the changes

---

Issues
The health bars keep there size, which looks alright on the default distance (1650), but looks stupid on a huge distance.